摘 要： 介紹了DSP—FLASH在線編程" title="在線編程">在線編程(ISP)與引導系統的硬件構成，給出了創建可引導文件的步驟和實現FLASH存儲器在線編程的算法；在AD公司Visual DSP++3.5集成開發環境下，通過JTAG對ADSP—21065L外部FLASH 存儲器AT29LV020實現在線編程，并完成系統的引導。
關鍵詞： JTAG FLASH 在線編程 引導 Visual DSP++3.5
在以DSP為核心的數字信號處理系統中，通常將可執行代碼存放在非易失性存儲器" title="非易失性存儲器">非易失性存儲器中，在系統加電或復位時通過DSP的引導加載" title="加載">加載(Boot Loader)機制將該代碼轉移到高速存儲器中執行。AD公司出品的ADSP SHARC系列DSP內部的非易失性存儲器因其資源有限，必須在外部加以擴展。FLASH存儲器具有容量大、單電源供電和可在線編程的特點，是一種非常理想的存儲器。
若采用燒錄器對FLASH存儲器進行編程，則在修改程序時必須拔插器件，而某些表貼封裝(如PLCC封裝和TSOP封裝)的器件又需要專用的轉接插座，這使得程序的調試和參數的修改非常繁瑣，而且容易對器件造成物理損傷。采用在線編程的方式對FLASH存儲器進行操作，可以克服上述問題，為調試者提供了極大的方便。本文以ADSP—21065L外部擴展的FLASH存儲器AT29LV020為對象，在Visual DSP++3.5環境中通過JTAG仿真器運行一段程序，將可引導代碼在線燒錄到FLASH中，并實現系統的引導。
1 在線編程與引導系統
本系統以ADSP—21065L及外部的FLASH存儲器AT29LV020為核心，由DSP控制FLASH存儲器的擦除和讀寫。
AT29LV020是用單電源3.3V供電的低功耗FLASH存儲器，容量2MB(256K×8)，8位數據總線，18位地址總線。該芯片以扇區(SECTOR)為基本的編程單位，共有1024個扇區，每個扇區包含256個字節。芯片的存儲空間中包含兩個引導區，分別是最低8K(0x00000～0x01FFF)和最高8K(0x3E000～0x3FFFF)的引導區[1～2]。
系統引導時，DSP將FLASH作為普通的外部數據存儲器，通過DMA方式訪問。ADSP—21065L的外部地址空間為0x00020000～0x03FFFFFF。FLASH的物理地址(ADD)對于DSP來說就是(0x00020000+ADD)。整片AT29LV020占據ADSP—21065L的外部地址空間范圍為0x00020000～0x0005FFFF，這段空間屬于Bank0。訪問該段空間時，DSP引腳
有效。引導時，DSP引腳
有效。所以，使用和的組合作為FLASH的片選信號。DSP與FLASH的連接如圖1所示[3]。
2 DSP可引導文件的創建
在線編程的過程如下：
(1)創建一個適合FLASH存儲器的引導程序" title="引導程序">引導程序文件A；
(2)在Visual DSP++ 3.5環境中編寫一個FLASH的操作程序，創建一個可執行的“.DXE”文件B；
(3)通過基于JTAG的Emulator將B下載到DSP中執行，將A文件寫入FLASH中。
下面介紹如何在Visual DSP++ 3.5的開發環境中創建一個可以引導的文件[4]。該文件就是通過JTAG寫入FLASH中的目標文件。具體步驟如下：
(1)創建一個將要寫入FLASH的源程序，在Visual DSP++環境中直接通過Emulator下載到DSP中執行，驗證程序的正確性。
(2)打開菜單Project→Project Options…，在Project標簽的頁面里，選擇Type為Loader File；在Load標簽的頁面里，選擇Boot Mode為Prom，選擇Boot Format為ASCII，并為將要創建的.LDR文件指定名稱。
(3)重新編譯工程，在工程目錄中得到一個載入文件*.LDR。
至此，一個可引導的文件就創建成功了。該文件的格式如下：
……
0x1254
0xCDF3
0x256C
……
該文件有n行，每行為一個雙字節的16進制數?？紤]到FLASH的數據總線是8位，在寫入之前，必須將每行分成兩個單字節的16進制數。
3 FLASH在線編程的實現
3.1 FLASH扇區編程的實現
AT29LV020的操作包括扇區編程、整片擦除、讀芯片ID、退出讀芯片ID、引導區加鎖等，這里關心的主要是扇區編程。
扇區是AT29LV020編程的最小操作單位，每次編程操作時，目標扇區的256個字節同時進行。在DSP的寫指令字序列的作用下，同一個扇區的256個字節被寫入FLASH內部的緩沖區，然后FLASH自動啟動編程操作。DSP向緩沖區寫入同一個扇區的數據時，數據的寫入順序是任意的，但是相鄰的寫信號間隔不能大于150μs，否則將被視為寫入操作完成，編程過程立刻啟動，而扇區內沒有寫入內容的地址將全部被編程為FF。完成一個扇區的編程最多只需要20ms。編程過程啟動后首先會自動擦除需要編程的扇區，所以在編程前并不需要對扇區進行單獨的擦除操作。
為了防止FLASH中的內容被誤操作或者其它操作修改，FLASH默認為寫保護狀態。每次對扇區進行編程前必須寫入一個命令字序列，才可以向FLASH的緩沖區寫入數據，進而啟動編程。編程結束后，FLASH自動恢復到寫保護狀態。
一個扇區編程是否結束，可以通過以下三種方法判斷：
(1)反復讀最后寫入的地址的內容，如果編程沒有結束，讀到數據的最高位與最后寫入的數據的最高位始終互為補碼；編程結束后，讀到的數據與最后寫入的數據相等。
(2)反復讀任意某個地址的內容，如果編程沒有結束，每次讀操作都會導致次高位發生跳變；編程結束后，讀到的結果就是寫入該地址的實際數據。
(3)寫完一個扇區后延時20ms，作為扇區編程結束的依據。
扇區編程的流程圖如圖2所示。
3.2 FLASH文件在線編程的實現
考慮到AT29LV020的最小編程單位為一個扇區，首先應該將待編程的文件分割為若干個256字節的編程單元，對于最后的一個單元，無論是否夠256字節，都無需理會，仍舊按照一個扇區處理。
假設待編程的文件名為filename.ldr，采用匯編語言編寫軟件時，使用變量定義：
.var f_data[ ] = 'filename.ldr';
緩沖區f_data[ ]的首址指向filename.ldr的首行，f_data的每個元素都對應文件的一行。由于創建的引導程序文件每行數據都是16位的，包含兩個8位字節，所以必須將其分解為兩部分后分別寫入FLASH。
軟件的流程如圖3所示。
4 測試實例
下面是將文件寫入FLASH的完整程序，在實際中已經調試成功。通過該程序將一段閃燈代碼blink.ldr寫入FLASH中，復位后，被寫入的代碼自動加載到DSP中執行。在編程過程中，ADSP-21065L的FLAG10引腳輸出周期為40ms的方波；編程結束后，FLAG8輸出周期為40ms的方波。
// 宏定義與變量初始化
#define f_size 1572 //文件的行數
#define mem_offset 0x020000 //FLASH的地址偏移
#define u_mem1_a 0x025555 //命令字寫入地址1
#define u_mem2_a 0x022AAA //命令字寫入地址2
#include ＜def21065L.h＞
.section/dm seg_fout;
.var f_data[] =“blink.ldr”; //待寫入的代碼文件
.section/dm seg_dmda;
.var d_byte;
.var addr;
.var line_num = 0; //當前扇區已寫入行數
.var byte_size; //待寫入代碼字節數-1
.var counter = 0; //延時的計數值
// 復位中斷
.section/pm pm_rsti;
nop;
jump start;
nop;
//以下是主程序
.section/pm seg_pmco;
start:
nop;
bit clr mode1 0x00001000; //屏蔽所有中斷
IRPTL = 0x0; //清除未響應中斷
r0 = 0x0050; //設置 FLAG10 和
dm(IOCTL) = r0; //FLAG8為輸出引腳
program:
i0 = f_data;
r2 = 0x0; //已經寫入的字節數-1
r3 = f_size;
r4 = r3 + r3;
r4 = r4 - 1;
dm(byte_size) = r4;
r6 = dm(line_num);
r7 = 0;
comp(r6,r7); // 判斷是否為新的扇區
if ne jump sect_load; // 不是，則直接向FLASH
//緩沖區寫入字節
sect_ulock: //是，首先寫命令字序列
r12 = 0xAA;
dm(u_mem1_a) = r12;
r12 = 0x55;
dm(u_mem2_a) = r12;
r12 = 0xA0;
dm(u_mem1_a) = r12;
sect_load:
r0 = dm(i0,1); //讀取一行數據
r1 = fext r0 by 0:8; // 獲得低字節
dm(d_byte) = r1;
dm(addr) = r2;
call load_byte; //向FLASH寫入低字節
r2 = r2+1;
r1 = fext r0 by 8:8; //獲得高字節
dm(d_byte) = r1;
dm(addr) = r2;
call load_byte; //向FLASH寫入高字節
r8 = dm(byte_size);
comp (r2,r8); //判斷文件是否全部寫完
if eq jump done; //是，則結束
r6 = dm(line_num); //否，判斷扇區是否結束
r6 = r6+1;
dm(line_num) = r6;
r7 = 128;
comp (r6,r7);
if lt jump prog_loop; //否，繼續向該扇區寫數據
sect_done: //是，等待20ms
nop;
call wait_DQ7;
ustat2 = dm(IOSTAT);
bit tgl ustat2 FLG10O;
dm(IOSTAT) = ustat2; //翻轉FLAG10
r6 = 0;
dm(line_num) = r6;
r2 = r2+1;
jump sect_ulock; //開始向新扇區寫數據
prog_loop:
r2 = r2+1;
jump sect_load;
done: //編程結束
nop;
call wait_DQ7;
ustat2 = dm(IOSTAT);
bit tgl ustat2 FLG8O; //翻轉FLAG8
dm(IOSTAT) = ustat2;
jump done;
load_byte: //寫字節子程序
i4 = dm(addr);
m4 = mem_offset;
r12 = dm(d_byte);
dm(m4,i4) = r12;
rts;
nop;
wait_DQ7: //20ms延時子程序
r0 = dm(counter);
r0 = r0+1;
dm(counter) = r0;
r1 = 0x59000;
comp(r0,r1);
if lt jump wait_DQ7;
r0 = 0;
dm(counter) = r0;
rts;
nop;
上面的程序是針對由ADSP-21065L和AT29LV020構成的磁懸浮數字控制系統編寫的，可行性與可靠性已經在實際應用中得到驗證。該程序具有良好的可移植性，稍作修改即可用于類似的在線編程系統，具有較強的實用價值。
參考文獻
1 Application Note: Atmel AT29 Flash Memories [Z]. Atmel Corporation, 1998.10
2 Data Sheet: 2-megabit (256K x 8) 3-volt Only Flash Memory AT29LV020 [Z]. Atmel Corporation, 2002.5
3 Engineer To Engineer Note: Interfacing Byte Programmed Flash Memories to the ADSP-2106x SHARC series [Z]. Analog Device Inc., 1999.7
4 劉書明，羅軍輝. ADSP SHARC系列DSP應用系統設計[M]. 北京：電子工業出版社，2003.2